#Excel – Come contare specifici caratteri o parole in una cella o intervallo

A volte può essere necessario conoscere quante volte uno specifico carattere, oppure una specifica parola, è contenuto all’interno di una cella o addirittura all’interno di un intervallo di celle.

Ecco le varie casistiche dettagliate una ad una.

Contare specifici caratteri in una cella

Per contare quante volte un carattere specifico appare in una cella, si utilizza una formula basata sulle funzioni SOSTITUISCI e LUNGHEZZA.

Contare specifici caratteri

Nell’esempio, la cella attiva contiene questa formula:

=LUNGHEZZA(B5)-LUNGHEZZA(SOSTITUISCI(B5;C5;""))

Come funziona questa formula

Questa formula funziona utilizzando SOSTITUISCI per rimuovere tutti i caratteri che devono essere contati nel testo di partenza. Quindi la lunghezza del testo (con i caratteri rimossi) viene sottratta dalla lunghezza del testo originale. Il risultato è il numero di caratteri che sono stati rimossi con SOSTITUISCI, che è uguale al numero di tali caratteri.

Caratteri maiuscoli e minuscoli

SOSTITUISCI è una funzione che differenzia tra maiuscole e minuscole. Se avete bisogno di contare le occorrenze sia maiuscole che minuscole di un carattere specifico, utilizzate la funzione MAIUSC all’interno di SOSTITUISCI per convertire il testo in maiuscolo prima di eseguire la sostituzione. Come carattere di ricerca dovrete poi fornirne uno maiuscolo.

=LUNGHEZZA(B8)-LUNGHEZZA(SOSTITUISCI(MAIUSC(B8);C8;""))

Contare specifici caratteri in un intervallo

Se avete bisogno di contare quante volte un carattere specifico appare in un intervallo di celle, è possibile farlo con una formula che utilizza le funzioni LUNGHEZZA e SOSTITUISCI, insieme con la funzione di MATR.SOMMA.PRODOTTO.

Contare caratteri specifici in un intervallo di celle

Nell’esempio, la cella attiva contiene questa formula:

=MATR.SOMMA.PRODOTTO(LUNGHEZZA(B5:B8)-LUNGHEZZA(SOSTITUISCI(B5:B8;"a";"")))

Come funziona questa formula

Per ogni cella nell’intervallo, SOSTITUISCI rimuove tutte le “a” dal testo, quindi LUNGHEZZA calcola la lunghezza del testo senza “a”. Questo numero viene poi sottratto dalla lunghezza del testo originale.

LEGGI:  #Excel - Come contare i valori univoci in un intervallo con CONTA.SE [Quick Tip]

Poiché stiamo usando MATR.SOMMA.PRODOTTO, il risultato di tutto questo calcolo è un elenco di elementi (una matrice), dove vi è un elemento per ogni cella dell’intervallo, e ogni elemento è un numero basato sul calcolo sopra descritto. In altre parole, abbiamo un elenco di conteggi del carattere specificato, con il numero di caratteri presenti in ogni cella.

MATR.SOMMA.PRODOTTO poi somma i numeri in questo elenco e restituisce un totale complessivo di tutte le celle dell’intervallo.

Caratteri maiuscoli e minuscoli

SOSTITUISCI è una funzione che differenzia tra maiuscole e minuscole. Se avete bisogno di contare le occorrenze, sia maiuscole che minuscole, di un carattere specifico, utilizzate la funzione MAIUSC all’interno SOSTITUISCI per convertire il testo in maiuscolo prima che avvenga la sostituzione. Come carattere di ricerca dovrete poi fornirne uno maiuscolo.

La forma generica modificata della formula potrebbe risultare simile a questa:

=MATR.SOMMA.PRODOTTO(LUNGHEZZA(rng)-LUNGHEZZA(SOSTITUISCI(MAIUSC(rng);caratt;"")))

Contare specifiche parole in una cella

Se avete bisogno di contare quante volte una specifica parola (o qualsiasi stringa) appare all’interno di una cella, è possibile utilizzare una formula che utilizza le funzioni SOSTITUISCI  e LUNGHEZZA.

Contare parole specifiche in una cella

Nel nostro esempio, in cella D5 abbiamo usato questa formula:

=(LUNGHEZZA(B5)-LUNGHEZZA(SOSTITUISCI(B5;C5;"")))/LUNGHEZZA(C5)

Come funziona questa formula

B5 è la cella al cui interno vogliamo contare la specifica parola, C5 contiene la stringa (parola o qualsiasi stringa) da contare.

SOSTITUISCI rimuove la stringa dal testo originale e LUNGHEZZA calcola la lunghezza del testo senza la sottostringa. Questo numero viene quindi sottratto dalla lunghezza del testo originale. Il risultato è il numero di caratteri che sono stati rimossi da SOSTITUISCI.

Infine, il numero di caratteri rimossi è diviso per la lunghezza della stringa. Perciò, se una stringa è lunga 5 caratteri, e ci sono 10 caratteri mancanti dopo che è stata rimossa dal testo originale, sappiamo che la sottostringa appare due volte nel testo originale.

Caratteri maiuscoli e minuscoli

SOSTITUISCI è una funzione case-sensitive. Se avete bisogno di contare sia le occorrenze maiuscole che quelle minuscole di una parola o di una stringa, utilizzate la funzione MAIUSC all’interno SOSTITUISCI per convertire il testo in maiuscolo prima di eseguire la sostituzione:

=(LUNGHEZZA(B8)-LUNGHEZZA(SOSTITUISCI(MAIUSC(B8);MAIUSC(C8);"")))/LUNGHEZZA(C8)

Poiché questa formula converte sia la stringa che il testo originale in maiuscolo prima di eseguire la sostituzione, funzionerà ugualmente bene con stringhe maiuscole o minuscole.

Contare specifiche parole in un intervallo

Se avete bisogno di contare quante volte una specifica parola (o qualsiasi stringa) appare all’interno di un intervallo di celle, è possibile farlo con una formula che utilizzi le funzioni SOSTITUISCI e LUNGHEZZA, all’interno di MATR.SOMMA.PRODOTTO.

Contare specifiche parole in un intervallo di celle

Nel nostro esempio, in cella C13 abbiamo utilizzato questa formula:

=MATR.SOMMA.PRODOTTO((LUNGHEZZA(B7:B10)-LUNGHEZZA(SOSTITUISCI(B7:B10;C4;"")))/LUNGHEZZA(C4))

Come funziona questa formula

B7:B10 è l’intervallo gamma all’interno del quale vogliamo contare la specifica parola, e C4 contiene il testo (parola o stringa) che vogliamo contare.

LEGGI:  #Excel - Come contare le celle contenenti valori diversi da x o y [Quick Tip]

Per ogni cella nell’intervallo, SOSTITUISCI rimuove la stringa dal testo originale e LUNGHEZZA calcola la lunghezza del testo senza la sottostringa. Questo numero viene quindi sottratto dalla lunghezza del testo originale. Il risultato è il numero di caratteri che sono stati rimossi da SOSTITUISCI.

Quindi, il numero di caratteri rimossi è diviso per la lunghezza della stringa. Così, se una stringa/parola è lunga 5 caratteri, e ci sono 10 caratteri mancanti dopo che è stata rimossa dal testo originale, sappiamo che la stringa/parola appare due volte nel testo originale.

Poiché il calcolo di cui sopra è racchiuso nella funzione MATR.SOMMA.PRODOTTO, il risultato è una matrice che contiene un numero per ogni cella nell’intervallo. Questi numeri rappresentano il numero di occorrenze della stringa in ogni cella. Per questo esempio, la matrice è simile alla seguente: {1.1.1.0}.

Infine, MATR.SOMMA.PRODOTTO somma insieme tutti gli elementi della matrice per ottenere le occorrenze totali della stringa nell’intervallo di celle.

Caratteri maiuscoli e minuscoli

SOSTITUTO è una funzione case-sensitive. Se avete bisogno di contare sia occorrenze maiuscole che minuscole di una parola o stringa, utilizzate la funzione MAIUSC all’interno SOSTITUISCI per convertire il testo in maiuscolo prima di eseguire la sostituzione:

=MATR.SOMMA.PRODOTTO((LUNGHEZZA(intervallo)-LUNGHEZZA(SOSTITUISCI((MAIUSC(intervallo));MAIUSC(testo);"")))/LUNGHEZZA(testo))

 

Copyright © 2014-2017  Office Academy. Tutti i diritti riservati.
Vai alla barra degli strumenti