#Excel – La funzione IDENTICO() – Parte 2

Nel nostro ultimo post abbiamo già iniziato a parlare della funzione IDENTICO() e della sua utilità, ad esempio, nel verificare una password inserita, facendo dipendere dal suo corretto inserimento la possibilità di apportare modifiche ad una cella.

Oggi continueremo l’analisi presentando nuovi casi pratici in cui la funzione IDENTICO() viene utilizzata per:

  • forzare l’utilizzo di lettere maiuscole;
  • trovare una corrispondenza esatta in un elenco (restituendo, ad esempio, un nome da un codice, oppure contando le corrispondenze esatte);
  • controllare ogni carattere inserito in una cella (per verificare, ad esempio, in quale carattere differiscono due codici inseriti in celle diverse).

Forzare l’utilizzo di lettere maiuscole

È anche possibile utilizzare la funzione IDENTICO() in “Convalida dati” per assicurarci che in una cella vengano inseriti solo caratteri maiuscoli. La formula da utilizzare è la seguente:

=IDENTICO(C2;MAIUSC(C2))

identico5

 

Se venisse utilizzata una qualunque lettera minuscola, apparirebbe un messaggio di errore.

Trovare una corrispondenza esatta in un elenco

Invece di confrontare semplicemente una cella con un’altra, potrebbe essere necessario trovare una corrispondenza esatta in una lista di valori. Se qualcuno digita il codice di un prodotto in una cella, questo codice sarà presente nel vostro elenco prodotti?

Nell’esempio qui sotto abbiamo un elenco di codici prodotto nell’intervallo A2:A6. Un cliente ordina un prodotto utilizzando il codice relativo e dobbiamo controllare se tale prodotto è nel nostro magazzino digitandolo nella cella C2.

LEGGI:  #Excel - Corrispondenza approssimativa in base a più criteri

La formula da inserire in D2 per verificare la corrispondenza esatta è

=O(IDENTICO($A$2:$A$6;C2))

ma essendo una formula matriciale va inserita premendo Ctrl+Maiusc+Invio (a quel punto Excel la trasforma in {=O(IDENTICO($A$2:$A$6;C2))}.

identico6

 

Restituire un nome da una corrispondenza esatta in un elenco

Una naturale evoluzione del caso precedente potrebbe permettere la restituzione della descrizione del prodotto digitandone il codice. Da notare che l’utilizzo della funzione IDENTICO() permette di distinguere tra AA1 e aa1, mentre altre funzioni, come il CERCA.VERT (eccone la scheda tecnica) tratterebbero questi codici come identici restituendo la descrizione del primo codice che incontrerebbero nell’elenco

identico7

La formula nella cella E2 utilizza 3 funzioni:

  • la funzione IDENTICO() controlla il codice digitato in D2 e verifica se c’è una corrispondenza esatta nella lista dei codici prodotto;
  • la funzione CONFRONTA() restituisce il numero di riga del risultato VERO e il codice ghFG45j si trova nella seconda riga dell’intervallo;
  • la funzione INDICE() restituisce il valore presente nella seconda riga dell’intervallo A2:A6 (Sedia).

La formula da utilizzare è la seguente:

=INDICE($A$2:$A$6;CONFRONTA(VERO;IDENTICO($B$2:$B$6;D2);0))

sempre da inserire in forma matriciale (con Ctrl+Maiusc+Invio).

Contare le corrispondenze esatte in un elenco

Anche in questo caso ci viene utile l’abilità di questa funzione di distinguere tra maiuscole e minuscole. Altre funzioni come CONTA.SE() considererebbe aa allo stesso modo di AA.

identico8

La formula in colonna D utilizza le funzioni IDENTICO() e MATR.SOMMA.PRODOTTO():

  • la funzione IDENTICO() controlla gli elementi in colonna C e verifica se c’è una corrispondenza esatta con l’elenco in colonna A;
  • la funzione MATR.SOMMA.PRODOTTO() restituisce il conteggio basato sul numero di risultati VERO.
=MATR.SOMMA.PRODOTTO(--IDENTICO($A$2:$A$11;C2))
INFO
I due segni di sottrazione (doppio unario) prima della funzione IDENTICO() convertono i VERO in 1 e i FALSO in 0

identico9

In alternativa a MATR.SOMMA.PRODOTTO() sarebbe possibile utilizzare la funzione SOMMA(), ma solo inserendola nella solita forma matriciale {=SOMMA(–IDENTICO($A$2:$A$11;C2))} .

Controllare ogni carattere in una cella

La formula IDENTICO() ci può dire se due stringhe corrispondono esattamente, ma potreste aver bisogno di sapere quale carattere delle due stringhe non è identico. Nell’esempio seguente ogni stringa ha 5 caratteri e i numeri da 1 a 5 sono inseriti come intestazione di colonna.

LEGGI:  Come usare SOMMA.SE in #Excel

identico10

La formula in D2 utilizza 2 funzioni:

  • la funzione STRINGA.ESTRAI() restituisce uno specifico carattere da A2 o da B2 a seconda del numero presente come intestazione di colonna (ad esempio nella formula mostrata sopra, per D2, è verificato il primo carattere delle due stringhe, in quanto il numero presente in D1 è “1”;
  • la funzione IDENTICO() confronta i due caratteri estratti dalla funzione STRINGA.ESTRAI().
=IDENTICO(STRINGA.ESTRAI($A2;D$1;1);STRINGA.ESTRAI($B2;D$1;1))

Abbiamo così completato il nostro viaggio approfondito sulle funzionalità della funzione IDENTICO().

Copyright © 2014-2017  Office Academy. Tutti i diritti riservati.
Vai alla barra degli strumenti